Compositions from Ferrers Diagrams

George Beck, Nov. 18, 2021

abstract

Think of the dots of the Ferrers diagram of an integer partition of n as a subset ℱ of the lattice points in the plane. Let ℒ be the set of lines of rational slope s passing through a lattice point and the convex hull of ℱ. Count the points of ℱthat lie on each line of ℒ (starting with the line with greatest y intercept) to form a composition of n. We enumerate various statistics for sets of such compositions.

introduction

To do calculations, load CORE-6.nb, select all, and evaluate (Shift-Enter). Then select and evaluate the code section here.

\[FreakedSmiley] Warning: Do not set x or y as variables... they are used as undefined global variables.

\[FreakedSmiley] Warning: Do not try to read CORE-6.nb, which is a messy unorganized toolkit.

code

Clear[x,y]

pointslope[s_,{x0_,y0_}]:=y-y0-s x+s x0

slopeintercept[s_]@y0_:=y-y0-s x

FerrersPoints@λ_:=Table[{#,-n+1}&/@Range[0,λ[[n]]-1],{n,Length@λ}]

intercepts[s_]@λ_:=Module[
{endpoints,distances,bottomintercept},
endpoints=Last/@FerrersPoints[λ];
distances=pointslope[s,#]&/@endpoints/.Thread[{x,y}->{0,0}];
bottomintercept=-pointslope[s,endpoints[[Position[distances,Max@distances][[1,1]]]]]/.Thread[{x,y}->{0,0}];Range[0,bottomintercept,-1/Denominator@s]
]/;s>0

intercepts[s_]@λ_:=Range[-s(First@λ-1),-(Length@λ-1),-1/Denominator@s]/;s<0

lattice@λ_:=Outer[List,
Range[0,First@λ-1],
Range[0,-Length@λ+1,-1]]

X[0]@λ_:=λ

X[∞]@λ_:=ConjugatePartition@λ

X[s_]@λ_:=(Count[#1,0]&)/@Transpose[(slopeintercept[s]/@intercepts[s][λ]/. Thread[{x,y}->#1]&)/@Join@@FerrersPoints[λ]]

graphics[0][λ_]:=Module[{fp},
fp=FerrersPoints[λ];
Framed@Graphics[{
InfiniteLine/@Transpose@{First/@fp,{1,0}+#&/@First/@fp},PointSize[0.015],Point[Join@@lattice@λ],
{EdgeForm[Black],LightGray,(Disk[#1,0.15]&)/@Join@@fp}
},
PlotLabel->Style[
Column[{
Row@{Style["X",Italic],"(",0,", ",Row@λ,") ="},
Row@λ,"\n"
},Alignment->Center],16],AspectRatio->Automatic,PlotRange->{{-0.5,First[λ]-0.5},{0.5-Length[λ],0.5}},ImageSize->200]
]

graphics[∞][λ_]:=Module[{fp},
fp=FerrersPoints[λ];
Framed@Graphics[{
InfiniteLine/@Transpose@{fp[[1]],{0,-1}+#&/@fp[[1]]},PointSize[0.015],Point[Join@@lattice@λ],
{EdgeForm[Black],LightGray,(Disk[#1,0.15]&)/@Join@@FerrersPoints[λ]}
},
PlotLabel->Style[
Column[{
Row@{Style["X",Italic],"(",∞,", ",Row@λ,") ="},
Row@ConjugatePartition@λ,"\n"
},Alignment->Center],16],AspectRatio->Automatic,PlotRange->{{-0.5,First[λ]-0.5},{0.5-Length[λ],0.5}},ImageSize->200]
]

graphics[s_][λ_]:=Module[
{i=intercepts[s][λ]},
Framed@Graphics[{
InfiniteLine/@Transpose@{{0,#}&/@i,{1,s+#}&/@i},PointSize[0.015],Point[Join@@lattice@λ],
{EdgeForm[Black],LightGray,(Disk[#1,0.15]&)/@Join@@FerrersPoints[λ]}
},
PlotLabel->Style[
Column[{
Row@{Style["X",Italic],"(",s,", ",Row@λ,") ="},
Row@X[s][λ],"\n"
},Alignment->Center],16],
AspectRatio->Automatic,PlotRange->{{-0.5,First[λ]-0.5},{0.5-Length[λ],0.5}},ImageSize->200]
]

𝓅@x_:=StripLastZeros@ReverseSort@x

ℳ[s_][n_]:=Module[
{p,allimages,uniqueimages},
p=IntegerPartitions@n;
allimages=Tally[X[s]/@p];
uniqueimages=First/@Select[allimages,Last@#==1&];
Select[p,MemberQ[uniqueimages,X[s]@#]&]
]

rev=Reverse;

λ={5,5,4,1};

fp=FerrersPoints@λ;

A006141PartitionQ@x_:=Min@x==Length@x

A006141Partitions@n_:=Select[IntegerPartitions@n,A006141PartitionQ]

𝒜@n_:=Intersection[
X[-1]/@#,
X[1]/@#]&[IntegerPartitions@n]

γ@z_:=Module[{α=Range@Length@z},Join[α,multisetComplement[ConjugatePartition@z,α]]]

Sylvester’s line problem (1893)

Given a finite set of points in the plane, not all on a line, there is a line through exactly two points of the set.

Melchior proved this in 1941 and Gallai proved it in 1944.
https://en.wikipedia.org/wiki/Sylvester% E2 %80 %93 Gallai_theorem

Graphics[{InfiniteLine[{{0,0},{1,1}}],EdgeForm[Black],LightGray,Disk[#,.1]&/@{{0,0},{1,0},{-1,0},{1,1},{0,-1},{3,1},{1,-2}}},PlotRange->3.5,ImageSize->200]

The conclusion may fail if the set of points is infinite.

Graphics[{InfiniteLine[-22+{{1,-4},{4,-2}}],PointSize[.01],Point[Join@@lattice@ConstantArray[16,16]]}]

partition

A partition of n is a weakly decreasing finite sequence of positive integers.

Example:

λ={5,5,4,1};

The numbers are called the parts and the length l(λ) is the number of parts of λ.

Here are the partitions of 4 and their lengths.

Grid[Transpose@{xx=IntegerPartitions@4,Length/@xx}]

It is typical to put a condition on the parts. Here is a distinct partition of 17: (12,4,1); no two parts are the same.

Here are all the distinct partitions of 7 and their lengths.

DistinctPartitions@7

We often compress the notation.

Row/@DistinctPartitions@7

Ferrers diagram of a partition λ

In the Ferrers diagram of λ, the number of dots in row k is the k-th part.

Grid[{
{"●","●","●","●","●","   5"},
{"●","●","●","●","●","   5"},
{"●","●","●","●","","   4"},
{"●","","","","","   1"}
}]

the conjugate partition λ' of λ

For the conjugate partition, transpose the Ferrers diagram and count the dots in each row.

The conjugate of λ is λ'=(4,3,3,3,2).

Text@Grid[{
{"●","●","●","●","","   4"},
{"●","●","●","","","   3"},
{"●","●","●","","","   3"},
{"●","●","●","","","   3"},
{"●","●","","","","   2"},
{"","","","","","    "},
{"5","5","4","1",""," 15"}
}]

ℱ(λ), the Ferrers points

Think of the Ferrers diagram as a set of points ℱ(λ) contained in the plane lattice (ℤ^2).

fp=FerrersPoints@λ;
Graphics[{
PointSize[.01],Point[Join@@Outer[List,Range[-2,6],Range[-5,2]]],
EdgeForm[{Black,Thick}],LightGray,(Disk[#1,0.15]&)/@Join@@fp},
AspectRatio->Automatic,
PlotRange->.8{{-2.5,6.5},{-5.5,2.5}},
Axes->True
]

Flipping this in the x axis is possible. My favorite footnote (from MacDonald): “Readers who prefer this convention should read this book upside down in a mirror.”

ℒ(s), the lattice lines of slope s∈ℚ

Let λ be a partition and s∈ℚ⋃{∞}. Let ℒ(s) be the set of lines of slope s through the lattice points (ℤ^2).

Graphics[{
Table[InfiniteLine[{{k,0},{k+1,-2}}],{k,-2.5,5,.5}],
PointSize[.02],Point[Join@@lattice@ConstantArray[6,6]]},
PlotRange->{{-.5,5.5},{-5.5,.5}}
]

𝒮(s,λ), the strip

There is a minimal strip 𝒮(s,λ) of slope s∈ℚ containing ℱ(λ).

fp=FerrersPoints@λ;
Show[
RegionPlot[-3<2x+y<8,{x,-3,7},{y,-6,3},
Epilog->{
PointSize[.01],Point[Join@@Outer[List,Range[-2,6],Range[-5,2]]],
{EdgeForm[{Black,Thick}],LightGray,(Disk[#1,0.15]&)/@Join@@fp}},
PlotStyle->Lighter@LightBlue
],
AspectRatio->Automatic,
PlotRange->{{-1.5,5.5},{-4.5,1.5}}
]

ℒ(s,λ), the lines in the strip

Let ℒ(s,λ)=ℒ(s)⋂𝒮(s,λ).

Order the set of lines ℒ(s,λ) by decreasing y intercepts as ((Subscript[l, 1]),(Subscript[l, 2]),…,(Subscript[l, k])).

fp=FerrersPoints@λ;
Graphics[{
Table[InfiniteLine[{{k,0},{k+1,-2}}],{k,-1.5,4,.5}],
PointSize[.01],Point[Join@@Outer[List,Range[-2,6],Range[-5,2]]],
{EdgeForm[{Black,Thick}],LightGray,(Disk[#1,0.15]&)/@Join@@fp},
Text[(Subscript[Style["l",Italic,18,Red], Style[1,Red]]),{3.2,2}],
Text[(Subscript[Style["l",Italic,18,Red], Style[2,Red]]),{2.8,1.8}],
Text[(Subscript[Style["l",Italic,18,Red], Style[3,Red]]),{2.4,1.6}],
Text[Style["↙",18,Red],{1.9,1.1}]},
AspectRatio->Automatic,
PlotRange->{{-2.5,6.5},{-5.5,2.5}}
]

I originally took the order up for negative slope and down for positive. I would not have found the bizarre-looking conjecture 18 otherwise.

X(0,λ)=λ and X(∞,λ)=λ'

For slope 0, the composition is the original partition.

For infinite slope, the composition is the conjugate.

Row[{graphics[0]@λ,Spacer[20],graphics[∞]@λ}]

X(s,λ) is usually a composition, not a partition

There are some exceptions.

X[-1]@{2,2}

graphics[-1]@{2,2}

parts can be zero

Grid[{
{graphics[-2]@{4},Spacer[20],graphics[2]@{4}},
{graphics[-1/2]@{4},Spacer[20],graphics[1/2]@{4}}}
]

small parts

If the slope is a/b and a or b are large relative to the partition, expect small parts.

Grid[{
{graphics[-2]@λ,Spacer[20],graphics[3]@λ},
{graphics[-1/3]@λ,Spacer[20],graphics[4/3]@λ}
}]

composition

A composition is a sequence of non-negative integers.

Examples: (1,2,1) or (2,0,2,1).

linear@{2,1,3,1,4}

reversing a composition

If c is a composition, let rev(c) be the composition with the terms of c in reverse order.

c={4,4,1,1};

linear@c

rev@c

linear@rev@c

join of two compositions

If c and d are compositions, define the join c⊔d of c and d to be the composition formed from the parts of c followed by the parts of d.

c={4,4,1,1};
d={5,2,5};

Join[c,d]

complement of two compositions

The composition complement keeps track of multiplicities and keeps what is left in order.

For example, (5,5,4,4,3,3,2,2,1,1) - (4,3,2,2)=(5,5,4,3,1,1).

𝓅=rev∘sort
maps a composition to a partition

If c is a composition, let 𝓅(c)=rev(sort(c)), that is, the partition with the same parts as c including multiplicity.

𝓅 is "sort then reverse".

c=RandomInteger[10,{5}]

𝓅@c

not necessarily smooth

A sequence is smooth if it changes by at most 1 from term to term.

Here are larger parts and a jump in the composition.

graphics[1]@{9,5,4,3,2,1}

symmetry X(s,λ)=X(1/s,λ')

The lines (Subscript[ℒ, s]) are symmetric about the line y=-x, as are the Ferrers diagrams of a partition λ and its conjugate.

Here s=0 and 1/0=∞ again.

Row[{graphics[0]@λ,Spacer[20],graphics[∞]@ConjugatePartition@λ}]

This shows X(3/4,λ)=X(4/3,λ').

Row[{graphics[3/4]@λ,Spacer[20],graphics[4/3]@ConjugatePartition@λ}]

a numerical example: X(1/4,(Subscript[𝒫, 8]))

Here s=1/4. The small dots stand for zeros for readability.

TableForm[Transpose@{
Row/@IntegerPartitions@8,
Row@*X[1/4]/@IntegerPartitions@8/. 0->"·"
},TableHeadings->{None,Text/@{"partition λ of 8",Row[{Style["X",Italic],"(1/4, λ)"}]}}]

notation

Let (Subscript[𝒫, n]) be the set of partitions of n and p(n)=|(Subscript[𝒫, n])| be the partition function.

Let (Subscript[𝒫, >1,n]) be the set of partitions not containing 1 as a part.

Let (Subscript[𝒟, n])= (Subscript[𝒟, 1,n]) be the distinct partitions of n (no part is repeated) and q(n)=|(Subscript[𝒟, n])|.

Let (Subscript[𝒟, g,n]) be the set of partitions of n with gaps at least g, where g=1,2,….

Let (Subscript[𝒟, >1,n]) be the set of distinct partitions not containing 1 as a part. Let (Subscript[q, >1])(n)=|(Subscript[𝒟, >1,n])|.

Δ is the difference operator. If x=(Subscript[((Subscript[x, j])), j=1]^∞) is a sequence, then Δ x=(Subscript[((Subscript[x, j+1])-(Subscript[x, j])), j=1]^∞).

In general, if f is a function and M is a multiset, f(M)={f(x)|x∈M}.

interlude

Counting the lines with exactly two points, exactly three points, and so on led to nothing particularly interesting.

The line vector for λ=(5,5,4,1) is (0,40,9,3,2).

There are 0 lines with exactly one point, 40 lines with exactly two points, 9  lines with exactly three points, 3 lines with exactly four points, and 2 lines with exactly five points.

Ask me if you’d like me to clean up this material and send it to you.

theorems and conjectures

1’s at the ends of X(s,λ)

If s≠0 or ∞, then X(s,λ) starts with a 1.

If s>0, the first line of  ℒ(s,λ) contains exactly one dot: the first dot of the first part of λ.

If s<0, the first line of ℒ(s,λ) contains exactly one dot: the last dot of the first part of the partition λ.

If s<0, then X(s,λ) ends with a 1.

The last line of ℒ(s,λ) contains exactly one dot: the first dot of the last part of λ.

X(-1,λ) is smooth

The idea is that this kind of thing cannot happen in a Ferrers diagram:

Ferrers@{2,2,2,3,4}

proof for s=-1

Suppose (Subscript[l, i]) and (Subscript[l, i+1]) are successive lines of ℒ(-1,λ). If (Subscript[c, i+1])-(Subscript[c, i])≥2, there would be a dot to the right and below the last dot of (Subscript[c, i]), which is the last dot of a part (Subscript[λ, j]) of λ. Then (Subscript[λ, j+1])>(Subscript[λ, j]), a contradiction. Similarly if (Subscript[c, i])-(Subscript[c, i+1])≥2.

Question 1: With s<0 and zeros deleted, X(s,λ) is smooth.

X(-1,λ) is weakly unimodal

proof for s=-1

Suppose (Subscript[c, i]), (Subscript[c, j]), (Subscript[c, k]) are parts of a composition with (Subscript[c, i])>(Subscript[c, j])<(Subscript[c, k]), where i<j<k. If lines i and j are on or below the main diagonal, the last dot of (Subscript[c, i]) is to the right and below the last dot of (Subscript[c, j]), which contradicts λ being weakly decreasing. Similarly, taking the conjugate partition, the lines i and j cannot be on or above the main diagonal, so they must straddle the main diagonal. Similarly, the lines j and k must straddle the main diagonal. But then j is both below and above the main diagonal, a contradiction. □

Question 2: With zeros deleted, X(s,λ) is weakly unimodal.

Here are the compositions for slope -1/2 of the partitions of 8 with and without zeros.

TableForm[Transpose@{
Row/@IntegerPartitions@8,
Row@*X[-1/2]/@IntegerPartitions@8
,
Row@DeleteCases[X[-1/2]@#,0]&/@IntegerPartitions@8
},TableHeadings->{None,Text/@{
Column[{"partitions","λ of 8"}],
Column[{
Row[{Style["X",Italic],"(-1/2,λ)"}],
"with zeros"}],
Column[{
Row[{Style["X",Italic],"(-1/2,λ)"}],
"without zeros"}]
}
}]

Same for slope s=3/2.

TableForm[Transpose@{
Row/@IntegerPartitions@8,
Row@*X[3/2]/@IntegerPartitions@8
,
Row@DeleteCases[X[3/2]@#,0]&/@IntegerPartitions@8
},TableHeadings->{None,Text/@{
Column[{"partitions","λ of 8"}],
Column[{
Row[{Style["X",Italic],"(3/2,λ)"}],
"with zeros"}],
Column[{
Row[{Style["X",Italic],"(3/2,λ)"}],
"without zeros"}]
}
}]

slope s=-1

Theorem 1. For λ a partition of n, X(-1,λ) is a smooth weakly unimodal composition of n into positive parts such that the first and last parts are 1.

proof

Put together the previous three proofs for the case s=-1.  □

graphics[-1]@λ

Here are the compositions for slope -1 of the partitions of 8.

TableForm[Transpose@{
Row/@IntegerPartitions@8,
Row@*X[-1]/@IntegerPartitions@8
},TableHeadings->{None,Text/@{"partition\nλ of 8",Row[{Style["X",Italic],"(-1, λ)"}]}}]

codomain of X(-1,·)

• Theorem 2: The size of the codomain of the function X(-1,·) acting on (Subscript[𝒫, n]) is A001522(n).

A001522, Number of n-stacks with strictly receding walls, or the number of Type A partitions of n in the sense of Auluck (1951). 
…
Also number of partitions of n with positive crank (n>=2), cf. A064391. - Vladeta Jovovic, Sep 30 2001

Joerg Arndt told me that the idea for the sequence A001522 came from this geometry.

Proof

If (Subscript[X, -1])(λ)=(Subscript[X, -1])(μ), each hook of λ can be slid by the same amount past the main diagonal to get μ. For example, X(-1,5541)=X(-1,44331).

Row[{graphics[-1]@λ,Spacer[20],graphics[-1]@{4,4,3,3,1}}]

Let c be a composition of n into positive parts that is smooth, weakly unimodal, and with m≥1 parts that achieve the maximum of c. Then there are m partitions (λ^i) (j=1,2,…,m) such that X((λ^i))=c.

To construct a Ferrer's diagram from c, choose one of the diagonals that achieves the maximum for c to be on the main diagonal. Then all the other diagonals are determined.

So the pre-images of each smooth weakly unimodal composition c of n equals the number of maximal values of c. In other words, such a composition has a pre-image. So the size of codomain equals the number of smooth weakly unimodal compositions of n, which is A001522(n). □

size of codomain and rearrangement 1

Theorem 3: The size of the codomain of the function X(1,·) acting on (Subscript[𝒫, n]) is q(n).

Or, after removing duplicates, the number of compositions in the multiset X(1,(Subscript[𝒫, n])) is q(n).

example:

Here are the partitions of 6 and their images under X(1,·).

IntegerPartitions@6

Row@*X[1]/@%

Remove duplicates and count:

Union@%

Length@%

PartitionsQ@6

Proof

Suppose λ,μ∈(Subscript[𝒟, n]) and λ≠μ. Let k be the first index for which (Subscript[λ, k])≠(Subscript[μ, k]); suppose (Subscript[λ, k])>(Subscript[μ, k]). Since μ is strictly decreasing, (Subscript[λ, k])>(Subscript[μ, k+j])-j for j=1,2,… so there is no dot in the Ferrers diagram of μ on the same antidiagonal as the last dot of (Subscript[λ, k]). Therefore X(1,λ)≠X(1,μ) and there are at least q(n) different sets in the codomain of X(1,·).

Now suppose ν∈(Subscript[𝒫, n])\(Subscript[𝒟, n]), that is, ν has some identical parts. Slide the dots along antidiagonals as far as possible NE. This gives an element η∈(Subscript[𝒟, n]) with X(1,ν)=X(1,η). Therefore every element of (Subscript[𝒫, n]) is in one of q(n) sets with constant X(1,·) value. □

Conjecture 1: For λ∈(Subscript[𝒫, n]), X(1,λ) is a rearrangement of λ' iff λ∈(Subscript[𝒟, n]).

Row[{graphics[∞]@{5,3,2},graphics[1]@{5,3,2}}]

example: n=8

X(1,λ) is a rearrangement of λ'.

TableForm[
xx=DistinctPartitions@8;
Transpose@{
Row/@xx,
Row@*X[1]/@xx,
Row@*ConjugatePartition/@xx
},
TableHeadings->{None,Text/@{"λ ∈ (Subscript[𝒟, 8])",Row[{Style["X",Italic],"(1, λ)"}],
"λ'"}
}
]

Row[{graphics[∞]@#," ",graphics[1]@#}]&@{6,6,5,5,4,3,1}

X(1,λ) is not a rearrangement of λ'.

TableForm[
Transpose@{
xx=Complement[IntegerPartitions@8,DistinctPartitions@8];
Row/@xx,
Row@*X[1]/@xx,
Row@*ConjugatePartition/@xx
},
TableHeadings->{None,Text/@{Row[{"λ ∈ (Subscript[𝒫, 8])"," \\ ",(Subscript[𝒟, 8])}],Row[{Style["X",Italic],"(1, λ)"}],
"λ'"}
}
]

numerical evidence

Table[Apply[And,Sort@X[1]@#==Sort@ConjugatePartition@#&/@DistinctPartitions@n],{n,20}]

Table[Apply[Or,Sort@X[1]@#==Sort@ConjugatePartition@#&/@Complement[IntegerPartitions@n,DistinctPartitions@n]],{n,20}]

Conjecture 2: The size of the codomain of the function X(1/k,·) acting on (Subscript[𝒫, n]) is the number of partitions of n in which no parts are multiples of k+1, where k=2,3,…

This generalizes Theorem 3.

numerical evidence

Table[Length@AtLeastGap2Partitions@n,{n,36}]

Table[Length@Union[X[1/2]/@IntegerPartitions@n],{n,36}]

↕
A000726 	Number of partitions of n in which no parts are multiples of 3.
1, 1, 2, 2, 4, 5, 7, 9, 13, 16, 22, 27, 36, 44, 57, 70, 89, 108, 135, 163, 202, 243, 297, 355, 431, 513, 617, 731, 874, 1031, 1225, 1439, 1701, 1991, 2341, 2731, 3197, 3717, 4333, 5022, 5834, 6741, 7803, 8991, 10375, 11923, 13716, 15723, 18038, 20628, 23603
	(Case k=4, i=3 of Gordon Theorem.)

Table[Length@Union[X[1/3]/@IntegerPartitions@n],{n,36}]

↕
A001935 	Number of partitions with no even part repeated; partitions of n in which no parts are multiples of 4.
...
	1, 1, 2, 3, 4, 6, 9, 12, 16, 22, 29, 38, 50, 64, 82, 105, 132, 166, 208, 258, 320, 395, 484, 592, 722, 876, 1060, 1280, 1539, 1846, 2210, 2636, 3138, 3728, 4416, 5222, 6163, 7256, 8528, 10006, 11716, 13696, 15986, 18624, 21666, 25169, 29190, 33808, 39104, 45164

Table[Length@Union[X[1/4]/@IntegerPartitions@n],{n,24}]

↕
A035959 		Number of partitions of n in which no parts are multiples of 5. 
...
	1, 1, 2, 3, 5, 6, 10, 13, 19, 25, 34, 44, 60, 76, 100, 127, 164, 205, 262, 325, 409, 505, 628, 769, 950, 1156, 1414, 1713, 2081, 2505, 3026, 3625, 4352, 5192, 6200, 7364, 8756, 10357, 12258, 14450, 17034, 20006, 23500, 27510, 32200, 37582, 43846, 51022

Table[Length@Union[X[1/5]/@IntegerPartitions@n],{n,24}]

↕
A219601 		Number of partitions of n in which no parts are multiples of 6. 	
...
	1, 1, 2, 3, 5, 7, 10, 14, 20, 27, 37, 49, 65, 85, 111, 143, 184, 234, 297, 374, 470, 586, 729, 902, 1113, 1367, 1674, 2042, 2485, 3013, 3645, 4395, 5288, 6344, 7595, 9070, 10809, 12852, 15252, 18062, 21352, 25191, 29671, 34884, 40948, 47985, 56146, 65592

Conjecture 3: The size of the codomain of the function X(1/2,·) acting on  (Subscript[𝒟, n]) is |(Subscript[𝒟, 2,n])|.

numerical evidence

Table[Length@AtLeastGap2Partitions@n,{n,36}]

Table[Length@Union[X[1/2]/@DistinctPartitions@n],{n,36}]

↕
A003114 		Number of partitions of n into parts 5k+1 or 5k+4.
...
1, 1, 1, 1, 2, 2, 3, 3, 4, 5, 6, 7, 9, 10, 12, 14, 17, 19, 23, 26, 31, 35, 41, 46, 54, 61, 70, 79, 91, 102, 117, 131, 149, 167, 189, 211, 239, 266, 299, 333, 374, 415, 465, 515, 575, 637, 709, 783, 871, 961, 1065, 1174, 1299, 1429, 1579, 1735, 1913, 2100, 2311, 2533, 2785

where X(s,·) is one-to-one

Theorem 4: The maximal subset of (Subscript[𝒫, n]) on which X(-1,·) is one-to-one is the set of stack polyominoes with square core. (A188674.)

A188674 		Stack polyominoes with square core. 		11
	1, 1, 0, 0, 1, 2, 3, 4, 5, 7, 9, 13, 17, 24, 31, 42, 54, 71, 90, 117, 147, 188, 236, 298, 371, 466, 576, 716, 882, 1088, 1331, 1633, 1987, 2422, 2935, 3557, 4290, 5177, 6216, 7465, 8932, 10682, 12731, 15169, 18016, 21387, 25321, 29955, 35353, 41696, 49063, 57689, 67698, 79375, 92896, 108633, 126817, 147922, 172272

Idea of proof

Sliding all the hooks of λ simultaneously gives a partition μ such that X(-1,λ)=X(-1,μ).

λ={5,5,4,1};

μ={4,4,3,3,1};

X[-1]@λ

X[-1]@μ

We cannot slide the third hook of μ because it is a column of two dots.

Row[{Ferrers@x,Spacer[20],Ferrers@x2}]

So the set ((Subscript[X, -1])^(-1))(1,1,2,3,3,2,2,1)) has two members.

Count[X[-1]/@IntegerPartitions@15,{1,1,2,3,3,2,2,1}]

On the other hand, the partition (15) can slide around to (1,1,1,…,1) for a total of 15 partitions for which (Subscript[X, -1])(λ)=(1,1,1,…,1). □

Grid@Partition[graphics[-1]/@{{15},{14,1},{13,1,1},{12,1,1,1}},2]

Corollary: The maximal subset S of (Subscript[𝒫, n]) on which X(1,·) is one-to-one is empty unless n is a triangular number, say (1/2)m(m+1), in which case S is the singleton {(m,m-1,…,3,2,1)}.

Proof

No hook can slide iff the partition is (n,n-1,…,3,2,1). □

Conjecture 4: For  s=-2,-3,-4, the function X (s,·) is one-to-one on (Subscript[𝒟, g,n]), g=1,2,3,….

numerical evidence

The function (Subscript[X, -2]) is one-to-one on (Subscript[𝒟, g,n]), g=1,2,….

Table[xx=X[-2]/@IntegerPartitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-2]/@DistinctPartitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-2]/@AtLeastGap2Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-2]/@AtLeastGap3Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-2]/@AtLeastGap4Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-2]/@AtLeastGap5Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

s=-3

Table[xx=X[-3]/@IntegerPartitions@n;Length[Union@xx]==Length[xx],{n,20}]

Table[xx=X[-3]/@DistinctPartitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[-3]/@AtLeastGap2Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[-3]/@AtLeastGap3Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[-3]/@AtLeastGap4Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[-3]/@AtLeastGap5Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

s=-4

Table[xx=X[-4]/@IntegerPartitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-4]/@DistinctPartitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-4]/@AtLeastGap2Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-4]/@AtLeastGap3Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-4]/@AtLeastGap4Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Table[xx=X[-4]/@AtLeastGap5Partitions@n;Length[Union@xx]==Length[xx],{n,30}]

Conjecture 5: The function X(1/k,·) is one-to-one on (Subscript[𝒟, g,n]) for g≥k.

numerical evidence

Tally[Row@*X[1/3]/@IntegerPartitions@8]

Tally[Row@*X[1/3]/@DistinctPartitions@12]

Tally[Row@*X[1/3]/@AtLeastGap2Partitions@20]

Tally[Row@*X[1/3]/@AtLeastGap3Partitions@20]

Length@Union[X[1/3]/@AtLeastGap3Partitions@20]

Length@AtLeastGap3Partitions@20

Here is a check up to n=50.

Table[xx=X[1/3]/@IntegerPartitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[1/3]/@DistinctPartitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[1/3]/@AtLeastGap2Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[1/3]/@AtLeastGap3Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[1/3]/@AtLeastGap3Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

Table[xx=X[1/3]/@AtLeastGap5Partitions@n;Length[Union@xx]==Length[xx],{n,50}]

number of zeros for a hook partition

graphics[-7/3]@{3,1,1,1}

For a hook partition λ as shown, we can count the number of times ℒ(s) misses the dots. If s=a/b with a and b coprime, (a-1)((Subscript[λ, 1])-1)+(b-1)(l(λ)-1).

number of parts for X(-1,(Subscript[𝒫, n]))

Similarly, the number of parts in the multiset X(-1,(Subscript[𝒫, n])) is (∑_(λ∈(Subscript[𝒫, n])))l(λ)+(Subscript[λ, 1])-1.

graphics[-1]@λ

number of 1’s

Conjecture 6: Let a(n) be the number of 1’s in the multiset X(1,(Subscript[𝒟, n])). Then Δ a(n)=q(n).

DistinctPartitions@5

X[1]/@DistinctPartitions@4

X[1]/@DistinctPartitions@5

numerical evidence

Table[Count[Flatten[X[1]/@DistinctPartitions@n],1],{n,60}]

Accumulate@PartitionsQ@Range@60

%==%%

Conjecture 7: Let a(n) be the number of 1's in the multiset X(1,(Subscript[𝒟, >1,n])). Then Δ a(n+1)=(Subscript[q, >1])(n+3).

numerical evidence

Table[Count[Flatten[X[1]/@DistinctPartitionsNo1@n],1],{n,60}]

Differences@%

↕
A025147 		Number of partitions of n into distinct parts >= 2. 		+30
78
	1, 0, 1, 1, 1, 2, 2, 3, 3, 5, 5, 7, 8, 10, 12, 15, 17, 21, 25, 29, 35, 41, 48, 56, 66, 76, 89, 103, 119, 137, 159, 181, 209, 239, 273, 312, 356, 404, 460, 522, 591, 669, 757, 853, 963, 1085, 1219, 1371, 1539, 1725, 1933, 2164, 2418, 2702, 3016, 3362, 3746, 4171, 4637, 5155

Conjecture 8: Let a(n) be the number of 1’s in the multiset X(-1,(Subscript[𝒫, n])). Then 1/2(Δ^2)a(n)=A002865(n+3).

graphics[-1]@{8,5,2}

A002865 Number of partitions of n that do not contain 1 as a part.

Shane Chern may have a proof.

numerical evidence

Count the number of 1’s in (Subscript[X, -1])((Subscript[𝒫, n])).

Table[Count[Flatten[X[-1]/@IntegerPartitions@n],1],{n,50}]

1/2Differences[%,2]

↕
A002865 		Number of partitions of n that do not contain 1 as a part.

	1, 0, 1, 1, 2, 2, 4, 4, 7, 8, 12, 14, 21, 24, 34, 41, 55, 66, 88, 105, 137, 165, 210, 253, 320, 383, 478, 574, 708, 847, 1039, 1238, 1507, 1794, 2167, 2573, 3094, 3660, 4378, 5170, 6153, 7245, 8591, 10087, 11914, 13959, 16424, 19196, 22519, 26252, 30701

OR

A187219 		Number of partitions of n that do not contain parts less than the smallest part of the partitions of n-1. 	
	1, 1, 1, 2, 2, 4, 4, 7, 8, 12, 14, 21, 24, 34, 41, 55, 66, 88, 105, 137, 165, 210, 253, 320, 383, 478, 574, 708, 847, 1039, 1238, 1507, 1794, 2167, 2573, 3094, 3660, 4378, 5170, 6153, 7245, 8591, 10087, 11914, 13959, 16424, 19196, 22519, 26252, 30701, 35717
Essentially the same as A002865, but here a(1) = 1 not 0.

number of 2’s

Conjecture 9: Let a(n) be the number of 2’s in the multiset X(1,(Subscript[𝒟, n])) and let b(n)=(Δ^2)a(n). Then b(2n-1)+b(2n)=A238479(n).

numerical evidence

a=Table[Count[Flatten[X[1]/@DistinctPartitions@n],2],{n,80}]

b=Differences[a,2]

{u,v}=bisect@b

u+v

↕
A238479 		Number of partitions of n whose median is not a part. 
	0, 0, 1, 1, 2, 3, 4, 5, 8, 10, 13, 18, 23, 30, 40, 50, 64, 83, 104, 131, 166, 206, 256, 320, 394, 485, 598, 730, 891, 1088, 1318, 1596, 1932, 2326, 2797, 3360, 4020, 4804, 5735, 6824, 8108, 9624, 11392, 13468, 15904, 18737, 22048, 25914, 30400, 35619, 41686

Conjecture 10: Let a(n) and b(n) be the number of 2’s in the multisets X(-1,(Subscript[𝒫, n]) ) and X(-1,(Subscript[𝒫, >1,n])), respectively. Then b(2n)=a(2n)-a(2n-1).

numerical evidence

b=Table[Count[Flatten[X[-1]/@IntegerPartitionsNo1@n],2],{n,60}]

{bodd,beven}=bisect@b

beven

from below

{aodd,aeven}=bisect@a

aeven-aodd

• Conjecture 11: Let a(n) be the number of 2’s in the multiset X(-1,(Subscript[𝒫, n])), b(n)=(Δ^3)a(n), and c(n)=(Δ^2)p(n). Then 1/2(b(2n-1)+b(2n))=c(2n+1).

numerical evidence

a=Table[Count[Flatten[X[-1]/@IntegerPartitions@n],2],{n,60}]

{u,v}=bisect@Differences[a,3]

1/2(b(2n-1)+b(2n))

(u+v)/2

c=Differences[Table[PartitionsP[n],{n,100}],2]

c(2n+1)

Take[Differences[Table[PartitionsP[n],{n,0,100}],2],{2,-1,2}]

Conjecture 12: Let (Subscript[ν, k])(n) be the number of k’s in X(-1,(Subscript[𝒫, n])), k=1,2,3,…. For even k, (Subscript[ν, k])(2n-1) is even, and for odd k, (Subscript[ν, k])(2n) is even.

numerical evidence

Count the 1’s.

t=Table[Flatten[X[-1]/@IntegerPartitions@n],{n,40}];

t2=Table[Flatten[X[-1]/@IntegerPartitions@n],{n,41,46}];

t3=Table[Flatten[X[-1]/@IntegerPartitions@n],{n,47,52}];

t4=Table[Flatten[X[-1]/@IntegerPartitions@n],{n,53,58}];

t1=t;

t=Join[t1,t2,t3,t4];

ν1=Count[#,1]&/@t

bisect@Differences[ν1,2]

%[[1]]/2

Count the 2’s.

ν2=Count[#,2]&/@t

bisect@Differences[ν2,2]

1/2%[[1]]

Count the 3’s.

ν3=Count[#,3]&/@t

bisect@Differences[ν3,2]

1/2%[[2]]

Count the 4’s.

ν4=Count[#,4]&/@t

bisect@Differences[ν4,2]

1/2%[[1]]

Count the 5’s.

ν5=Count[#,5]&/@t

bisect@Differences[ν5,2]

1/2%[[2]]

Count the 6’s.

ν6=Count[#,6]&/@t

bisect@Differences[ν6,2]

1/2%[[1]]

rearrangement 2

• Conjecture 13: For g≥2 and n>1, X(1,λ) is a rearrangement of X(1/2,λ) iff λ∈(Subscript[𝒟, g,n]).

example: δ∈(Subscript[𝒟, 2,74]).

δ={20,18,13,10,7,5,1};

Total@δ

-Differences@δ

Row[{graphics[1]@δ,graphics[1/2]@δ}]

X[1]@δ

X[1/2]@δ

Sort@X[1]@δ==Sort@X[1/2]@δ

The rearrangement does not look obvious.

ListLinePlot@{X[1]@δ,X[1/2]@δ}

numerical evidence

Table[xx=AtLeastGap2Partitions@n;ReverseSort@*X[1]/@xx==ReverseSort@*X[1/2]/@xx,{n,24}]

Here dots represent 1’s for readability.

TableForm[Transpose@{Row/@AtLeastGap2Partitions@16,Row@*X[1]/@(AtLeastGap2Partitions@16)/. 1->"·",Row@*X[1/2]/@(AtLeastGap2Partitions@16)/. 1->"·"},
TableHeadings->{None,Text/@{"λ ∈ (Subscript[𝒟, 2, 16])",Row[{Style["X",Italic],"(1, λ)"}],Row[{Style["X",Italic],"(1/2, λ)"}]}}]

TableForm[Transpose@{Row/@AtLeastGap3Partitions@16,Row@*X[1]/@(AtLeastGap3Partitions@16)/. 1->"·",Row@*X[1/2]/@(AtLeastGap3Partitions@16)/. 1->"·"},
TableHeadings->{None,Text/@{"λ ∈ (Subscript[𝒟, 3, 16])",Row[{Style["X",Italic],"(1, λ)"}],Row[{Style["X",Italic],"(1/2, λ)"}]}}]

TableForm[Transpose@{Row/@AtLeastGap4Partitions@16,Row@*X[1]/@(AtLeastGap4Partitions@16)/. 1->"·",Row@*X[1/2]/@(AtLeastGap4Partitions@16)/. 1->"·"},
TableHeadings->{None,Text/@{"λ ∈ (Subscript[𝒟, 4, 16])",Row[{Style["X",Italic],"(1, λ)"}],Row[{Style["X",Italic],"(1/2, λ)"}]}}]

Table[xx=Complement[IntegerPartitions@n,AtLeastGap2Partitions@n];ReverseSort@*X[1]/@xx==ReverseSort@*X[1/2]/@xx,{n,24}]

intersections, complements, and rearrangement 3

Let (Subscript[𝒜, n])=X(1,(Subscript[𝒫, n]))⋂X(-1,(Subscript[𝒫, n])).

X[1]/@IntegerPartitions@5

X[-1]/@IntegerPartitions@5

𝒜@5

• Conjecture 14: |(Subscript[𝒜, n])|=|(Subscript[𝒟, 2,n])| .

Here is a candidate bijection γ between the two sets. Let λ∈(Subscript[𝒟, 2,n]) have l parts and let α(λ)=(1,2,3,…,l). Let γ(λ)=α(λ)⊔(λ'-α(λ)), where "-" is the multiset complement and "⊔" is multiset join (or concatenation of sequences).

In the other direction, 𝓅 is a candidate bijection from (Subscript[𝒜, n]) to (Subscript[𝒟, 2,n])'.

example: Let λ=(11,7,5); then  γ(λ)=(1,2,3,3,3,3,3,2,1,1,1)∈(Subscript[𝒜, n]).

numerical evidence

Table[Sort[γ/@AtLeastGap2Partitions@n]==Sort[𝒜@n],{n,36}]

Table[Sort[ConjugatePartition/@AtLeastGap2Partitions@n]==Sort[𝓅/@𝒜@n],{n,36}]

Conjecture 15: |𝓅((Subscript[𝒜, n])) \ (Subscript[𝒟, >1,n])'|=A006141(n).

A006141 		Number of integer partitions of n whose smallest part is equal to the number of parts.

I tried to find a bijection but failed.

numerical evidence

Table[
Length@Complement[
Sort[𝓅/@𝒜],
Sort[ConjugatePartition/@DistinctPartitionsNo1@n]
],{n,40}]

↕
A006141 		Number of integer partitions of n whose smallest part is equal to the number of parts.
	1, 0, 0, 1, 1, 1, 1, 1, 2, 2, 3, 3, 4, 4, 5, 6, 7, 8, 10, 11, 13, 15, 17, 19, 23, 25, 29, 33, 38, 42, 49, 54, 62, 69, 78, 87, 99, 109, 123, 137, 154, 170, 191, 211, 236, 261, 290, 320, 357, 392, 435, 479, 530, 582, 644, 706, 779, 854, 940, 1029, 1133, 1237, 1358, 1485

Table[Length@A006141Partitions@n,{n,20}]

Conjecture 16: (Subscript[𝒟, >1,n])'⊂𝓅((Subscript[𝒜, n])).

numerical evidence

SubsetQ[𝓅/@𝒜@12,ConjugatePartition/@AtLeastGap2No1Partitions@12]

SubsetQ[𝓅/@𝒜@24,ConjugatePartition/@AtLeastGap2No1Partitions@24]

Table[
Length@Intersection[
Sort[Sort/@Intersection[X[-1]/@IntegerPartitions@n,X[1]/@IntegerPartitions@n]],
Sort[Sort@*ConjugatePartition/@DistinctPartitionsNo1@n]
],{n,40}]

yy=Table[
xx=IntegerPartitions@n;
Length@Intersection[
Sort[Sort/@Intersection[X[-1]/@xx,X[1]/@xx]],
Sort[Sort@*ConjugatePartition/@DistinctPartitionsNo1@n]
],{n,41,60}]

Join[{0,1,1,1,1,2,2,3,3,4,4,6,6,8,9,11,12,15,16,20,22,26,29,35,38,45,50,58,64,75,82,95,105,120,133,152,167,190,210,237},yy]

↕
A003106 		Number of partitions of n into parts 5k+2 or 5k+3.
...
	1, 0, 1, 1, 1, 1, 2, 2, 3, 3, 4, 4, 6, 6, 8, 9, 11, 12, 15, 16, 20, 22, 26, 29, 35, 38, 45, 50, 58, 64, 75, 82, 95, 105, 120, 133, 152, 167, 190, 210, 237, 261, 295, 324, 364, 401, 448, 493, 551, 604, 673, 739, 820, 899, 997, 1091, 1207, 1321, 1457, 1593, 1756, 1916, 2108, 2301

Table[SubsetQ[𝓅/@𝒜@n,ConjugatePartition/@AtLeastGap2No1Partitions@n],{n,12}]

Let (Subscript[ℬ, n])=X(1,(Subscript[𝒫, n])) \ X(-1,(Subscript[𝒫, n])),
and (Subscript[ℰ, n]) be the set of distinct partitions of n that include a pair of consecutive integers.

Conjecture 17: |(Subscript[ℬ, n])|=|(Subscript[ℰ, n])| and each element of (Subscript[ℬ, n]) is a rearrangement of an element of (Subscript[ℰ, n])'.

A238708, Number of strict partitions of n that include a pair of consecutive integers.

numerical evidence

t41to56=Table[Length@Complement[X[1]/@IntegerPartitions@n,X[-1]/@IntegerPartitions@n],{n,41,56}]

t=Table[Length@Complement[X[1]/@IntegerPartitions@n,X[-1]/@IntegerPartitions@n],{n,40}]

↕
A238708 		Number of strict partitions of n that include a pair of consecutive integers. 	
	0, 0, 0, 1, 0, 1, 1, 2, 2, 3, 4, 5, 6, 8, 10, 13, 15, 19, 23, 28, 33, 41, 48, 58, 68, 81, 95, 113, 131, 154, 179, 209, 241, 281, 323, 374, 429, 494, 565, 649, 739, 845, 961, 1095, 1241, 1411, 1595, 1807, 2039, 2303, 2593, 2923, 3283, 3691, 4139, 4643, 5195

other way gives nothing

z=Table[Length@Complement[X[-1]/@IntegerPartitions@n,X[1]/@IntegerPartitions@n],{n,40}]

t+z

z-t

{c,d}=bisect@%

d-c

Differences[d-c,2]

c+d

xa=Table[Length@Complement[X[1/2]/@IntegerPartitions@n,X[-2]/@IntegerPartitions@n],{n,20}]

rearrangements

Row/@With[{n=12},Complement[X[1]/@IntegerPartitions@n,X[-1]/@IntegerPartitions@n]]

Row/@Select[DistinctPartitions@12,MemberQ[Differences@#,-1]&]

Row@*ConjugatePartition/@Select[DistinctPartitions@12,MemberQ[Differences@#,-1]&]

Sort[Sort/@With[{n=12},Complement[X[1]/@IntegerPartitions@n,X[-1]/@IntegerPartitions@n]]]

Sort[Sort/@ConjugatePartition/@Select[DistinctPartitions@12,MemberQ[Differences@#,-1]&]]

Table[Sort[Sort/@Complement[X[1]/@IntegerPartitions@n,X[-1]/@IntegerPartitions@n]]==Sort[Sort/@ConjugatePartition/@Select[DistinctPartitions@n,MemberQ[Differences@#,-1]&]],{n,24}]

• Conjecture 18: Let a(n)=|rev(X(-2,(Subscript[𝒫, n])))⋂X(1/2,(Subscript[𝒫, n])))|. Then a(2n-1)=A078408(n) and a(2n)=A035294(n)+A003114(n).

A078408,	Number of ways to partition 2n+1 into distinct positive integers.
A035294, Number of ways to partition 2n into distinct positive integers. 
A003114, Number of partitions of n into parts 5k+1 or 5k+4. (The size of (Subscript[𝒟, 2,n]).)

numerical evidence

a(n)

Table[Length@
Intersection[
Reverse/@X[-2]/@IntegerPartitions@n,
X[1/2]/@IntegerPartitions@n
],{n,48}]

(a(2n-1),a(2n))

{u,v}=bisect@%

↕
u=a(2n-1): 
A078408 		Number of ways to partition 2n+1 into distinct positive integers. 
	1, 2, 3, 5, 8, 12, 18, 27, 38, 54, 76, 104, 142, 192, 256, 340, 448, 585, 760, 982, 1260, 1610, 2048, 2590, 3264, 4097, 5120, 6378, 7917, 9792, 12076, 14848, 18200, 22250, 27130, 32992, 40026, 48446, 58499, 70488, 84756, 101698, 121792, 145578

u=a(2n-1)=q(2n-1)

Table[PartitionsQ[2n-1],{n,24}]

w=Table[PartitionsQ[2n],{n,24}]

↕
A035294 		Number of ways to partition 2n into distinct positive integers. 
	1, 1, 2, 4, 6, 10, 15, 22, 32, 46, 64, 89, 122, 165, 222, 296, 390, 512, 668, 864, 1113, 1426, 1816, 2304, 2910, 3658, 4582, 5718, 7108, 8808, 10880, 13394, 16444, 20132, 24576, 29927, 36352, 44046, 53250, 64234, 77312, 92864, 111322, 133184, 159046

v-w

↕
A003114 		Number of partitions of n into parts 5k+1 or 5k+4.
	1, 1, 1, 1, 2, 2, 3, 3, 4, 5, 6, 7, 9, 10, 12, 14, 17, 19, 23, 26, 31, 35, 41, 46, 54, 61, 70, 79, 91, 102, 117, 131, 149, 167, 189, 211, 239, 266, 299, 333, 374, 415, 465, 515, 575, 637, 709, 783, 871, 961, 1065, 1174, 1299, 1429, 1579, 1735, 1913, 2100, 2311, 2533, 2785

to do

Proofs!

Find the inverse of X(s,λ). Look at the algorithm for finding λ' for inspiration.

For a partition λ, a composition contains numbers other than 0 and 1 iff the slope s equals the slope determined by a pair of points of ℱ(λ). So that finite set of slopes is interesting. The set of slopes containing only 0’s and 1’s is infinite and might also be interesting.

The rays through the origin of slope s∈(-∞,∞) intersect the unit circle in an open unit semi-circle U in the right half-plane, which can be mapped by straight lines from the origin to the line x=1. Take a set of fractions S distributed uniformly on U and consider X(s,λ), s∈S. There are critical slopes (SubMinus[s]) and (SubPlus[s]) for which the compositions consist of only 0’s and 1’s outside of ((SubMinus[s]),(SubPlus[s])).

Lay out the parts of a composition (strict or not) as rows of dots like ℱ(λ) and consider their compositions. Also stacks.

Why is  A001522 the number of partitions of n of positive crank (n>1)?

The geometry of plane partitions looks challenging but doable. However, it might be better to count points on lattice planes, which gives an ordinary composition, rather than on lines, which gives a spread-out polygonal array of numbers.

Compositions for various sets of partitions.

reference

Some variants of Ferrers diagrams
James Propp

Journal of Combinatorial Theory Series A Volume 52 Issue 1 Sep. 1989 pp 98–128 https://doi.org/10.1016/0097-3165(89)90066-6